Simple Audit for Microsoft Dynamics GP: Create Triggers

This post is part of a series on creating a simple audit for Microsoft Dynamics GP.

With the table created to store the audited information, the second step is to create the required triggers on the Address Electronic Funds Transfer Master (SY06000) table. For an Vendor EFT audit there are three triggers required:

1. INSERT
2. UPDATE
3. DELETE

These triggers will record all new Vendor EFT information added as well as that which is amended or deleted. The client for which this audit was created only dealt with vendors in the UK and only ever set three fields in the EFT Bank window:

1. Bank Name
2. EFT Bank Code
3. EFT Bank Account

Additional fields can be added to the audit if other fields need to be stored.

As the Address Electronic Funds Transfer Master (SY06000) table holds EFT Bank information for customers as well as vendors, the Record ID has been set to include the Series. Strictly speaking, this was not necessary as the client did not store bank details for their customers in Dynamics GP as none were making direct debit payments.

The audited data is being trimmed and cast as varchar so the extra whitespace held by Dynamics GP due to the columns being chars are removed.

The first trigger creates the trigger which runs when data is inserted:

/*
Created by Ian Grieve of azurecurve | Ramblings of an IT Professional (http://www.azurecurve.co.uk)
This code is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0 Int).
*/
CREATE TRIGGER utr_AZRCRV_SY06000_AuditInsert ON SY06000 AFTER INSERT AS
INSERT INTO
	ut_AZRCRV_Audit
--VALUES
	SELECT
		'Vendor EFT'
		,CAST(i.SERIES AS VARCHAR(100)) + ' | ' + CAST(RTRIM(i.CustomerVendor_ID) AS VARCHAR(100)) + ' | '  + CAST(RTRIM(i.ADRSCODE) AS VARCHAR(100))
		,'Insert'
		,SYSTEM_USER
		,GETDATE_USER()
		,''
		,'BANKNAME = ' + CAST(RTRIM(i.BANKNAME) AS VARCHAR(100)) + ' | ' + 'EFTBankCode = ' + CAST(RTRIM(i.EFTBankCode) AS VARCHAR(100)) + ' | ' + 'EFTBankAcct = ' + CAST(RTRIM(i.EFTBankAcct) AS VARCHAR(100))
	FROM
		inserted i
GO

The second trigger creates the trigger which runs when data is updated:

/*
Created by Ian Grieve of azurecurve | Ramblings of an IT Professional (http://www.azurecurve.co.uk)
This code is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0 Int).
*/
CREATE TRIGGER utr_AZRCRV_SY06000_AuditUpdate ON SY06000 AFTER UPDATE AS
INSERT INTO
	ut_AZRCRV_Audit
--VALUES
	SELECT
		'Vendor EFT'
		,CAST(d.SERIES AS VARCHAR(100)) + ' | ' + CAST(RTRIM(d.CustomerVendor_ID) AS VARCHAR(100)) + ' | '  + CAST(RTRIM(d.ADRSCODE) AS VARCHAR(100))
		,'UPDATE'
		,SYSTEM_USER
		,GETDATE_USER()
		,'BANKNAME = ' + CAST(RTRIM(d.BANKNAME) AS VARCHAR(100)) + ' | ' + 'EFTBankCode = ' + CAST(RTRIM(d.EFTBankCode) AS VARCHAR(100)) + ' | ' + 'EFTBankAcct = ' + CAST(RTRIM(d.EFTBankAcct) AS VARCHAR(100))
		,'BANKNAME = ' + CAST(RTRIM(i.BANKNAME) AS VARCHAR(100)) + ' | ' + 'EFTBankCode = ' + CAST(RTRIM(i.EFTBankCode) AS VARCHAR(100)) + ' | ' + 'EFTBankAcct = ' + CAST(RTRIM(i.EFTBankAcct) AS VARCHAR(100))
	FROM
		deleted d
	LEFT JOIN
		inserted i
			ON
				i.SERIES = d.SERIES
			AND
				i.CustomerVendor_ID = d.CustomerVendor_ID
			AND
				i.ADRSCODE = d.ADRSCODE
GO

The third trigger creates the trigger which runs when data is deleted:

/*
Created by Ian Grieve of azurecurve | Ramblings of an IT Professional (http://www.azurecurve.co.uk)
This code is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0 Int).
*/
CREATE TRIGGER utr_AZRCRV_SY06000_AuditDelete ON SY06000 AFTER DELETE AS
INSERT INTO
	ut_AZRCRV_Audit
--VALUES
	SELECT
		'Vendor EFT'
		,CAST(d.SERIES AS VARCHAR(100)) + ' | ' + CAST(RTRIM(d.CustomerVendor_ID) AS VARCHAR(100)) + ' | '  + CAST(RTRIM(d.ADRSCODE) AS VARCHAR(100))
		,'Delete'
		,SYSTEM_USER
		,GETDATE_USER()
		,'BANKNAME = ' + CAST(RTRIM(d.BANKNAME) AS VARCHAR(100)) + ' | ' + 'EFTBankCode = ' + CAST(RTRIM(d.EFTBankCode) AS VARCHAR(100)) + ' | ' + 'EFTBankAcct = ' + CAST(RTRIM(d.EFTBankAcct) AS VARCHAR(100))
		,''
	FROM
		deleted d
GO